gelöst: Bericht 2x Drucken

[miho]

Hallo

Ich habe ein Makro welches mir einen Bericht über ein Unterformular öffnet. Ich habe versucht es noch so zu erweitern, dass der Bericht zweimal ausgedruckt wird und sich dann wieder schliesst. Leider sind mein Kenntnisse dazu zu gering. Kann mir jemand helfen?
SUB Filtern_und_Drucken
DIM oDoc AS OBJECT
DIM oDrawpage AS OBJECT
DIM oForm AS OBJECT
DIM oFeld AS OBJECT
DIM oDatenquelle AS OBJECT
DIM oVerbindung AS OBJECT
DIM oSQL_Anweisung AS OBJECT
DIM stSQL AS STRING
oDoc = thisComponent
oDrawpage = oDoc.Drawpage
oForm = oDrawpage.Forms.getByName("search").getByName("lieferanten").getByName("bescheinigungen").getByName("Annahme")
oFeld = oForm.getByName("BELEG")
oDatenquelle = ThisComponent.Parent.CurrentController
If NOT (oDatenquelle.isConnected()) THEN
oDatenquelle.connect()
END IF
oVerbindung = oDatenquelle.ActiveConnection()
oSQL_Anweisung = oVerbindung.createStatement()
stSql = "UPDATE ""filterBELEG"" SET ""Integer"" = '"+oFeld.GetCurrentValue()+"' WHERE ""ID"" = TRUE"
oSQL_Anweisung.executeUpdate(stSql)
ThisDatabaseDocument.ReportDocuments.getByName("Abgabe pro Lieferant").open
END SUB

[F3K Total]

Ohne Test, versuche mal dies ... sollte den Bericht 2x zum Drucker schicken:

Code: Alles auswählen

SUB Filtern_und_Drucken
    DIM oDoc AS OBJECT
    DIM oDrawpage AS OBJECT
    DIM oForm AS OBJECT
    DIM oFeld AS OBJECT
    DIM oDatenquelle AS OBJECT
    DIM oVerbindung AS OBJECT
    DIM oSQL_Anweisung AS OBJECT
    DIM stSQL AS STRING
    DIM printProp(1) as new com.sun.star.beans.PropertyValue
    oDoc = thisComponent
    oDrawpage = oDoc.Drawpage
    oForm = oDrawpage.Forms.getByName("search").getByName("lieferanten").getByName("bescheinigungen").getByName("Annahme")
    oFeld = oForm.getByName("BELEG")
    oDatenquelle = ThisComponent.Parent.CurrentController
    If NOT (oDatenquelle.isConnected()) THEN
    oDatenquelle.connect()
    END IF
    oVerbindung = oDatenquelle.ActiveConnection()
    oSQL_Anweisung = oVerbindung.createStatement()
    stSql = "UPDATE ""filterBELEG"" SET ""Integer"" = '"+oFeld.GetCurrentValue()+"' WHERE ""ID"" = TRUE"
    oSQL_Anweisung.executeUpdate(stSql)
    odocument = ThisDatabaseDocument.ReportDocuments.getByName("Abgabe pro Lieferant").open
    printProp(0).name = "Wait"
    printProp(0).Value = true
    printProp(1).name = "CopyCount"
    printProp(1).Value = 2
    odocument.Print(printProp())
    msgbox (" Der Bericht wurde 2x zum Drucker geschickt",64,"Ausdruck gestartet")
END SUB

Gruß R

[miho]

Herzlichen Dank! Es klappt wunderbar! Liebe Grüsse und die besten Festtagswünsche! m